***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Jul 24, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt PJSD05TS-AU A K
.param
+vc1 = 1.064e-11
+tc1 = 4.657e-2
+tc2 = 7.492e-3
+rr1 = 7.155e-14
+rr2 = 2.875
+rrt = 1.616e-2
d1 A K zener
g1 K A value ={(vc1*v(K,A)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25))))+(rr1*exp(rr2*v(K,A))*(1.0+rrt*(temp-25)))}
.model zener d
***** flag parameter ***
+level = 1                     
***** dc model parameter ***
+ibv = 1e-3
+bv = 6.7
+is = 5.352e-16
+n = 1.023
+rs = 0.156
***** capacitance parameter ***
+cjo = 1.1247e-10
+vj = 0.628
+m = 0.326
+fc = 0.5                      
***** temperature coefficient ***
+tnom = 25                     
+eg = 1.127
+xti = 3                       
+tbv1 = 3.703e-4
+trs1 = 9.065e-4
.ends PJSD05TS-AU
*$
